WebTiger

WebTiger Kullanımı

WebTiger ürünü ile kullanılan Logo uygulamasında terminal tanımı olmaksızın, intranet üzerinden ile IIS yüklü bir servera ulaşıp Malzeme Yönetimi, Finans, Satış ve Dağıtım, Satınalma vb. gibi tüm modüllerde raporlama yapılır. Mevcut Navigator fonksiyonlarından farklı olarak WebTiger fonksiyonlarının başında altçizgi (_) olmayacaktır. Örn; (DBINFO,STCALC...) WebTiger fonksiyonlarına kolay ulaşım için fonksiyon listesinde Select Catagory alanından "User Defined" seçilmelidir.

WebTiger kullanılacak makinada, sql server'ın adresinin tanımlandığı URL adresi, rapor fonksiyonlarını kullanmaya yetkili kullanıcı adı ve kullanıcı şifresinin tanımlanacağı Excel template dosyasının çalıştırılması gerekmektedir.

Özel Kullanım Durumları

Filtre kullanılmaması durumunda filtre satırına iki tane çift tırnak( " ") yazılmalıdır. =AcCalc(1;100;A7;A8;"";1;1;1)

DBINFO ile alınan değerlerde "Kullanımda" / "Kulanım Dışı" olmasa bile 3 hepsi kullanılmalıdır. Örnek ÖTV Kodunun Getirtilmesi =DBInfo(A6;21;6;"";3)

DBINFO gibi fonksiyonlarda CODE alanı kullanılmasa bile " " ile geçilmelidir. =DBInfo(A6;4;6;"";1) 

Filtrede İki Değerin Bir Arada Kullanılması

=AcCalc(1;100;A7;A8;"OHP:[111,112]";1;1;1)

Yukardaki fonkiyon 100 kasa hesabındaki masraf merkezi 111 ve 112 olan borç değerlerinin toplamını getirmektedir.

İki Filtrenin Bir Arada Kullanılması

=AcCalc(1;100;A7;A8;"OHP:[113] FSC:[A]";1;1;1)

Yukardaki kullanımda 100 kasa hesabındaki masraf merkezi 111 ve 112 olan ve fiş özel kodu A olan fişlerin borç değerlerinin toplamını getirmektedir.

? İşaretinin Filtrede Kullanımı

=AcCalc(1;100;A7;A8;"OHP:[?11]";1;1;1)

Yukardaki kullanımda 100 kasa hesabındaki masraf merkezi kodunun ilk karakteri ne olursa olsun son iki karakteri 11 olan toplam borç değerini getirecektir.

* İşaretinin Filtrede Kullanımı

=AcCalc(1;100;A7;A8;"OHP:[1*]";1;1;1)

Yukardaki kullanımda 100 kasa hesabına masraf merkezi kodunun ilk karakteri bir, sonraki karakterleri ne olursa olsun toplam borç değerini getirecektir.( 111,121,1A001... Masraf merkezlerinin değerleri gelir.)

- İşaretinin Hariç Olarak Kullanılması

=AcCalc(1;100;A7;A8;"OHP:-[113]";1;1;1)

Yukardaki kullanımda 100 kasa hesabına masraf merkezi 113 haricindeki borç değerlerinin toplamını getirmektedir.

* İşaretinin Birden Fazla Kez Kullanımı

=AcCalc(1;100;A7;A8;"OHP:[1*,3*]";1;1;1)

Yukardaki kullanımda 100 kasa hesabına masraf merkezi kodunun ilk karakteri 1 ve 3 ile başlayıp sonraki karakteri ne olursa olsun toplam borç değerini getirecektir. (Masraf merkezi kodları :111,121,145,333,345)

- Ve * İşaretinin Hariç Olarak Kullanılması

=AcCalc(1;100;A7;A8;"OHP:-[12*,3*]";1;1;1)

Yukardaki kullanımda 100 kasa hesabına masraf merkezi kodunun ilk iki karakteri 12 ve 3 ile başlayan masraf merkezleri haricindeki toplam borç değerini getirecektir. (Masraf merkezi kodları : 11,14 ile başlayanlarda yansıyacaktır.

~ İşaretinin Arasında Olarak Kullanımı

=AcCalc(1;100;A7;A8;"OHP:[111~122]";1;1;1)

Yukardaki kullanımda 100 kasa hesabında masraf merkezi 111 ve 122 arasında olan (111 ve 122 dahil) borç değerlerinin toplamını getirmektedir.

~ Ve *(%) İşaretinin Bir Arada Kullanımı

=AcCalc(1;100;A7;A8;"OHP:[12%~3%]";1;1;1)

Yukardaki kullanımda 100 kasa hesabında masraf merkezi 12 ile başlayan ve 3 ile başlayanlara kadar olan masraf merkezi haricindeki borç değerlerinin toplamını getirmektedir.

=AcCalc(1;100;A7;A8;"OHP:[12%~3Z%]";1;1;1) olarak kullanıldığında ise,

100 kasa hesabında masraf merkezi 12 ile başlayan ve 3 ile başlayanlar haricindeki (2 grubu da dahil) borç değerlerinin toplamını getirmektedir.

~ ,*(%) Ve - İşaretinin Bir Arada Kullanımı

% İşaretide * isareti gibi Like olarak çalışmaktadır.

=AcCalc(1;100;A7;A8;"OHP:-[1%~2%]";1;1;1) (Hatalı)

=AcCalc(1;100;A7;A8;"OHP:-[1%~2Z%]";1;1;1) (Doğru Kullanım)

Yukardaki kullanımda 100 kasa hesabında masraf merkezi 1 ile başlayan ve 2 ile başlayanlar haricindeki borç değerlerinin toplamını getirmektedir.

2Z kullanılmasının nedeni belirtilen -[1%~ 2%] 'da 2'nin tutarının gelmesinin sebebi 2%'nin 2'den sonra gelen karakterlerden küçük olmasından kaynaklandığı tespit edilmiştir. SQL bu şekilde çalışmaktadır. Navi'de ise filtre [1%~2Z%] şeklinde kullanılmalıdır.

CONCATENATE Fonksiyonunun Kullanımı

Concatenate fonksiyonu Excel içinde birden fazla metinsel alanı birleştirmek için kullanılmaktadır. Navigatorda kulanım amacı ise navigator fonksiyonunda filtre alanlarına yazılacak değerleri Excel'de bir hücreye yazılan değeri okutmak amacıyla kullanılır.

A12: Filtrede vermek istediğiniz masraf merkezi kodu yazılır.

A13: Filtrede vermek istediğiniz ikinci masraf merkezi kodu yazılır.

A14: Filtrede vermek istediğiniz fiş özel kodu filtresi yazılır. 

Masraf Merkezi Kodunu Filtrede Kullanma

=AcCalc(1;100;A7;A8;CONCATENATE("OHP:[";A12;"]");1;1;1) 

Birden Fazla Masraf Merkezi Kodunu Filtrede Kullanma

=AcCalc(1;100;A7;A8;CONCATENATE("OHP:[";A12;";";A13;"]");1;1;1) 

Masraf Merkezi Kodu Ve Fiş Özel Kodunun Filtre Olarak Kullanılması

=AcCalc(1;100;A7;A8;CONCATENATE("OHP:[";A12;";";A13;"]";"FSC:[";A14;"]");1;1;1)

SQLINFO Fonksiyonunun Kullanımı

A16: Malzeme Kodu yazılır.

=SQLINFO("NAME";"LG_001_ITEMS";CONCATENATE("CODE='";A16;"'"))

=SQLINFO("NAME";"LG_001_ITEMS";"CODE='"&A16&"'")

=SQLINFO("CODE";"LG_001_EMUHACC";CONCATENATE("LOGICALREF=";A19))

=SQLINFO("CODE";"LG_001_EMUHACC";"LOGICALREF="&A19) 

Örnek1: Aşağıdaki fonksiyon ile malzemenin barkod numarası getirilir

A22 HUCRESINE: Malzeme kodu yazılır.

=SQLINFO("A.BARCODE";"LG_001_ITMUNITA A,LG_001_ITEMS

I";CONCATENATE("I.LOGICALREF=A.ITEMREF AND I.CODE='";A22;"'")) 

Örnek2: Aşağıdaki fonksiyon ile bir banka hesabının tarih ve özel kod verilere borç alacak değerlerinin listelenmesi

B2 HUCRESINE TARIH: '2005-01-01 (Başta Tek Tırnak işareti vardır.)

B3 HUCRESINE TARIH: '2005-12-31 (Başta Tek Tırnak işareti vardır.)

B5 HUCRESINE: Filtrede Kullanılacak Özel Kod yazılır.

C6 HUCRESINE: Banka Hesabının Kodu yazılır.

C9 HUCRESINE: Banka Kodu yazılır. 

a-) BANKA Kodunun Logıcalref Değerinin Bulunması (B9 Hücresi)

=SQLINFO("LOGICALREF";"LG_001_BNCARD";CONCATENATE("CODE='";C9;"'")) 

b-)BANKA Hesap Numarasının Logıcalref Değeri Bulunur (B6 Hücresi)

=SQLINFO("LOGICALREF";"LG_001_BANKACC";CONCATENATE("CODE='";C6;"'")) 

c-) İlgili Banka Hesabının Belli Tarih Aralığı Ve Hareket Özel Koduna Gore Alacak Değerinin Listelenmesi

=VALUE(SQLINFO("SUM(AMOUNT*ABS(SIGN))";"LG_001_01_BNFLINE";CONCATENATE("BANKREF='";$B9;"' AND BNACCREF='";$B6;"' AND SPECODE='";$B$5;"' AND DATE_ BETWEEN '";$B$7;"' AND '";$B$8;"'"))) 

d-) İlgili Banka Hesabının Belli Tarih Aralığı Ve Hareket Özel Koduna Gore Borç Değerinin Listelenmesi

=VALUE(SQLINFO("SUM(AMOUNT*ABS(SIGN-1))";"LG_001_01_BNFLINE";CONCATENATE("BANKREF='";$B9;"' AND BNACCREF='";$B6;"' AND SPECODE='";$B$5;"' AND DATE_ BETWEEN '";$B$7;"' AND '";$B$8;"'"))) 

Örnek3: Aşağıdaki Fonksiyon ile Borç takipteki belirli bir tarih aralığındaki kodu 0 ile başlayan carilerin toptan satış faturalarının toplamını listelemektedir.

B7 HUCRESINE TARIH: '2005-01-01 (Başta Tek Tırnak işareti vardır.)

B8 HUCRESINE TARIH: '2005-12-31 (Başta Tek Tırnak işareti vardır.)

B11 HÜCRESİNİN FORMATI: Sayı ve kuruş hanesi 2 yapılır.

=VALUE(SQLINFO("SUM(P.TOTAL)";"LG_001_01_PAYTRANS P,LG_001_CLCARD C ";CONCATENATE("C.LOGICALREF=P.CARDREF AND C.CODE LIKE '0%' AND P.MODULENR=4 AND P.TRCODE=8 AND P.DATE_BETWEEN '";B$7;"' AND '";B$8;"'")))