BeginForm(Basla)
    Set(@kullanici,@@LoginUser.Name+" "+@@LoginUser.Surname)    
    ShowMessage({"title":"Oturum Açıldı", "message" : " HOŞGELDİNİZ \n @kullanici", "buttons" : "OK"},@secim)
    GoForm(AnaMenu)    
EndForm()

BeginForm(Cikis)
    Logout()
EndForm()

BeginForm(AnaMenu)
    KeyFunction("ESC",GoForm(Basla))
    ClearScreen()
    MenuItem(SayimMenu,"Sayım İşlemleri","",2)
    MenuItem(Cikis,"Çıkış","",22)
    MenuRun(0,1,"Ana Menü")
EndForm()

BeginForm(SayimMenu)
    KeyFunction("ESC",GoForm(AnaMenu))
    ClearScreen()
    MenuItem(SayimBas,"Sayım","",11)
    MenuItem(Cikis,"Çıkış","",22)
    MenuRun(0,1,"Sayım Islemleri")
EndForm()

BeginForm(SayimBas)
    KeyFunction("ESC",GoForm(SayimMenu))
    ResetVariables()
    ClearScreen()
    CallForm(KaynakDepoSecim)
    Text(0,0,"Sayım  |  @@Warehouse.Code @@Warehouse.Name")
    FisBul:
        WorkOrder.Get("WarehouseId=@@Warehouse.Id and SlipType=5 and StateId= 12 and Active=1")
        If(@@WorkOrder.Id="")
            ShowMessage({"title":"Uyarı", "message" :"Açık Sayım Emri bulunamadı!","buttons" :"Tamam"},@sec)
            GoForm(SayimBas)
        Else()
            Slip.Get("WorkOrderId=@@WorkOrder.Id")
            If(@@Slip.Id="")
                Slip.New({"SlipType":"5"},1) 
            EndIf()
        EndIf()
        GoForm(SayimDetay) 
EndForm()     

BeginForm(SayimDetay)
    KeyFunction("ESC",GoForm(SayimBas))
    ClearScreen()
    Text(0,0,"Sayım  |  @@Warehouse.Code @@Warehouse.Name")
    Set(@SlipType,5)
    AdresBul:
        ResetVariables({"name":["@@Address","@kadres"]})
        ClearScreen()
        CallForm(KaynakAdresKontrol)
        If(@kadreskontrolet!=0,Goto(KaynakAdresGir))
        Text(1,1,"Adres :@kadres")
        Goto(Palet)
    KaynakAdresGir:
        Input(1,1,"Adres  :",{"type":"text","min":"1","max":"12"},@kadres)
        CallForm(KaynakAdresSorgu)
        If(@SonucKaynakAdres!=0,Goto(KaynakAdresGir))
    Palet:
        ResetVariables({"name":["@@Container","@palet"]})
        Input(1,2,"Palet |[.]Paletsiz Islem :",{"type":"text","min":"1","max":"15"},@palet)
        If(@palet=".",Goto(Barkoda))
        CallForm(PaletKontrolSorgu)
        If(@SonucPaletKontrolSorgu!=0,Goto(Palet))
    Barkoda:
        If(@palet=".")
            ResetVariables({"name" :["@@Container"]})
            Text(1,2,"Palet :Paletsiz Giriş")
            Goto(Barkod)
        EndIf()
        Text(1,2,"Palet :@palet")
    Barkod:
        ClearLines(3,3)
        ClearLines(4,4)
        ResetVariables({"name" :["@@Item","@takipno"]})
        Input(1,3,"Barkod | [.] Malzeme Filtresi : ",{"type":"text","min":"1","max":"30"},@barkodk)
        CallForm(QRSorgu)
        If(@kontrolet=1)
            Set(@degiskenata,1)
            Goto(TakipTuru)
        Else()
            If(@kontrolet=2)
                Set(@degiskenata,2)
                Goto(TakipTuru) 
            EndIf()
        EndIf()
        Set(@degiskenata,"")
        Goto(Barkod)
    TakipTuru:
        ClearLines(3,3)
        Text(1,3,"Malzeme Kodu :@@Item.Code | Malzeme Adı :@@Item.Name")
        CaseGoto(@@Item.TrackingType,{"0":"Takipsiz","1":"Lot","2":"Seri"})
    Lot:
        If(@degiskenata=2)
            If(@@Container.Id!="")
                Sql("select convert(date,MIN(ExpirationDate)) as date from TransactionDetail where TrackingNumber=@takipno and ItemId=@@Item.Id and WarehouseId=@@Warehouse.Id and UnitId=@@ItemUnit.Id and AddressId=@@Address.Id and ContainerId=@@Container.Id",@sktkont)
            Else()
                Sql("select convert(date,MIN(ExpirationDate)) as date from TransactionDetail where TrackingNumber=@takipno and ItemId=@@Item.Id and WarehouseId=@@Warehouse.Id and UnitId=@@ItemUnit.Id and AddressId=@@Address.Id",@sktkont)
            EndIf()
            If(@sktkont.rows.1.date="")
                Goto(SktGir)
            EndIf()
            Left(@sktkont.rows.1.date,10,@skt)
            CallForm(SayimKontrol)
            If(@SayimKontrol=0)
                Text(1,4,"Lot Takip No |Skt :@takipno |@skt")
                Goto(Miktar)
            EndIf()
            Text(1,4,"Lot Takip No |Skt :@takipno |@skt")
            ShowMessage({"title":"Uyarı","message":"@takipno nolu ürünün sayım miktarı\n\n @sayimmiktar @@ItemUnit.Code güncellensin mi ?","buttons":"Evet|Hayır"},@secim12)
            If(@secim12=2)
                Goto(Barkod)
            EndIf()
            Text(1,4,"Lot Takip No |Skt :@takipno |@skt")
            Goto(Miktar)
        EndIf()
    LotGir:
        ResetVariables({"name" :["@takipno"]})
        Input(0,0,"Takip No : ",{"type":"text","min":"1","max":"15"},@takipno)  
    SktGir:
        ResetVariables({"name" :["@skt"]})
        Input(0,0,"Son Kullanma Tarihi : ", {"type":"date","min":"01-01-2020","max":"31-12-2030"},@skt)
        Set(@skt,"@skt.1"+"."+"@skt.2"+"."+"@skt.3")
        If(@skt.isDate!="0")
            ShowMessage({"title":"Hata","message":"Tarih Formatı Hatalı","buttons":"Yeniden Gir"},@sec)
            Goto(SktGir) 
        EndIf()
        Text(1,4,"Lot Takip No |Skt :@takipno|@skt")
        CallForm(SayimKontrol)
        If(@SayimKontrol!=0)
            ShowMessage({"title":"Uyarı","message":"@takipno nolu ürünün sayım miktarı\n\n @sayimmiktar @@ItemUnit.Code güncellensin mi ?","buttons":"Evet|Hayır"},@secim12)
            If(@secim12=2)
                Goto(Barkod)
            EndIf()
        EndIf()
        Goto(Miktar)
    Seri:
        Set(@miktar,1)
        If(@degiskenata=2)
            Text(1,4,"Seri Takip No :@takipno")
            CallForm(SayimKontrol)
            If(@SayimKontrol=0)
                Set(@miktar,1)
                Goto(SatirOlustur)
            Else()
                ShowMessage({"title":"Uyarı","message":"@takipno lu ürün @kadres adresinde daha önce sayılmış!","buttons":"Tamam"},@sec)
                Goto(Barkod)
            EndIf()
        EndIf()
    SeriGir:
        ResetVariables({"name":["@takipno"]})
        Input(0,0,"Seri Takip No :",{"type":"text","min":"1","max":"30"},@takipno)
        Text(1,4,"Seri Takip No :@takipno")
        CallForm(SayimKontrol)
        If(@SayimKontrol=0)
            Set(@miktar,1)
            Goto(SatirOlustur)
        Else()
            ShowMessage({"title":"Uyarı","message":"@takipno lu seri @kadres adresinde daha önce sayılmış!","buttons":"Tamam"},@sec)
            Goto(Barkod)
        EndIf()
    Takipsiz:
        Text(1,4,"Takipsiz Ürün")
        CallForm(SayimKontrol)
        If(@SayimKontrol!=0)
            ShowMessage({"title":"Uyarı","message":"Ürünün sayım miktarı\n\n@sayimmiktar @@ItemUnit.Code güncellensin mi ?","buttons":"Evet|Hayır"},@secim123)
            If(@secim123=2)
                Goto(Barkod)
            EndIf()
        EndIf()
    Miktar:   
        If(@SayimKontrol!=0,Goto(Miktara))
        Input(1,5,"Miktar :",{"type":"decimal", "min":"1.0", "max":"9999999.0"},@miktar)
        If(@SayimKontrol=0,Goto(SatirOlustur))
    Miktara:
        Text(1,5,"Miktar :@sayimmiktar")
        Input(1,6,"Güncellenecek Miktar :",{"type":"decimal", "min":"1.0", "max":"9999999.0"},@miktar)
    SatirGuncelle:
        If(@@Item.TrackingType!="0")
            ItemTracking.Get("LineType=5 AND TrCode=5 AND SlipLineId=@@SlipLine.Id AND TrackingNumber='@takipno'")
            ItemTracking.Set({"Quantity":"@miktar"})
            ItemTracking.Save()
        Else()
            //Set(@@SlipLine,{"Quantity":"@miktar"})
            //SlipLine.Save()
            Sql("update SlipLine set Quantity=@miktar where Id=@@SlipLine.Id",@def)
            Sql("update TransactionDetail set Quantity=@miktar where WorkOrderLineId=@@WorkOrderLine.Id",@sonuc)
        EndIf()
        ShowMessage({"title":"Bilgi","message":"İşlem Başarılı bir şekilde gerçekleşti","buttons":"Tamam"},@sec)
        Goto(AdresBul)
    SatirOlustur:
        If(@@Item.TrackingType="0")
            SlipLine.New({"SlipType":"@SlipType", "Quantity":"@miktar"},1)
        Else()
            SlipLine.New({"SlipType":"@SlipType", "Quantity":"@miktar"},0)
            ItemTracking.New({"LineType":"5","Quantity":"@miktar","TrackingNumber":"@takipno","ExpirationDate":"@skt"},1)
        EndIf()
        ShowMessage({"title":"Bilgi","message":"İşlem Başarılı bir şekilde gerçekleşti","buttons":"Tamam"},@sec)
        Goto(AdresBul) 
EndForm()

BeginForm(KaynakDepoSecim)
    KeyFunction("ESC",GoForm(AnaMenu))
    ClearScreen()
    ResetVariables({"name":"@@Warehouse"})
    Warehouse.List("","",@wh1)
    If(@wh1.rowCount=0)
        ShowMessage({"title":"Hata","message" :"Depo bulunamadı","buttons":"TAMAM"},@secim)
        GoForm(SayimMenu)
    EndIf()
    PopupView(@wh1.rows,{"mode":"list","title":"Kaynak Depo","fields":["Code|Kodu|10|L","Name|Adı|20|L"]},@kdeposu)
    Warehouse.Get(@wh1.rows.@kdeposu.Id)
    If(@Response.Status = "-1")
        ShowMessage({"title": "Hata", "message" : "Kayıt bulunamadı","buttons": "TAMAM"},@secim2)
        Goto(KaynakDepoSecim)
    EndIf()
    ReturnForm()
EndForm()

BeginForm(KaynakAdresKontrol)
    Set(@kadreskontrolet,0)
    Address.List("WarehouseId=@@Warehouse.Id","",@kadresKontrol)
    If(@kadresKontrol.rowCount=1,Goto(Adrestek))
    Set(@kadreskontrolet,-1) 
    ReturnForm()
    Adrestek:    
        Address.Get(@kadresKontrol.rows.1.Id)
        Set(@kadres,@@Address.Address)
        ReturnForm()
EndForm()

BeginForm(KaynakAdresSorgu)
    Set(@SonucKaynakAdres,0)
    Address.Get("Address='@kadres' and WarehouseId=@@Warehouse.Id")
    If(@@Address.Id="")
        ShowMessage({"title":"Hata!","message":"@kadres Adresi Kayıtlı Değil","buttons":"Tamam"},@hata)
        Set(@SonucKaynakAdres,-1)
    EndIf()
    ReturnForm()
EndForm()

BeginForm(PaletKontrolSorgu)
    Set(@SonucPaletKontrolSorgu,0)
    Container.Get("LPN='@palet'",@@Container)
    If(@@Container.Id ="")
        ShowMessage({"title":"Uyarı!","message":"@palet numaralı taşıma kabı bulunamadı","buttons":"Tamam"},@secim)
        Set(@SonucPaletKontrolSorgu,-1)
        ReturnForm()    
    EndIf()
    ReturnForm()
EndForm()

BeginForm(QRSorgu)
    If(@barkodk=".")
        CallForm(ItemAra)
        If(@@Item.Id="")
            Set(@kontrolet,3)
            ReturnForm()
        EndIf()
        Set(@kontrolet,1)
    Else()
        UnitBarcode.Get("Barcode='@barkodk'")
        If(@@Item.Id="")
            //Malzeme Kodundan Kontrol Et
            Item.Get("Code='@barkodk'")
            If(@@Item.Id="")
                //ShowMessage({"title":"Hata","message" :"Barkod Kayıtlı Degil","buttons":"Tamam"},@secim6)
                Goto(BarkodKontrol)
            EndIf()
        EndIf()
        Set(@kontrolet,1)
        Set(@barkod,@barkodK)
    EndIf()
    ReturnForm()
    BarkodKontrol:
        Set(@kontrolet,2)
        Split(@barkodk,|,@qrkont)
        Set(@barkod,@qrkont.1)
        Set(@takipno,@qrkont.2)
        //SplitRegex(@barkodk,"([a-zA-Z0-9.\-\*]+)|([a-zA-Z0-9.\-\*]+)",@qrkont)
        //Set(@barkod,@qrkont.1)
        //Set(@takipno,@qrkont.2)
        UnitBarcode.Get("Barcode='@barkod'")
        If(@@Item.Id="")
            //Malzeme Kodundan Kontrol Et
            Item.Get("Code='@barkod'")
            If(@@Item.Id="")
                ShowMessage({"title":"Hata","message" :"Barkod Kayıtlı Degil","buttons":"Tamam"},@secim6)
                Set(@kontrolet,3)
                ReturnForm()
            EndIf()
            ReturnForm()
        EndIf()
        ReturnForm()
EndForm()

BeginForm(SayimKontrol)
    ResetVariables({"name":["@@PlanningSlipLine","@@SlipLine","@@WorkOrderLine"]})
    Set(@SayimKontrol,0)
    If(@palet=".")
        Set(@parametre,"")
    Else()
        Set(@parametre,"AND ContainerId=@@Container.Id")
    EndIf()
    WorkOrderLine.Get("SlipId=@@WorkOrder.Id AND ItemId=@@Item.Id AND AddressId=@@Address.Id @parametre")
    If(@@WorkOrderLine.Id="")
        If(@@Item.TrackingType="0")
            WorkOrderLine.New({"SlipType":"5","Quantity":"0"},1)
        Else()
            WorkOrderLine.New({"SlipType":"5","Quantity":"0"},0)
            ItemTracking.New({"LineType":"4","Quantity":"0","TrackingNumber":"@takipno","ExpirationDate":"@skt"},1)
        EndIf()
        ReturnForm()
    Else()
        SlipLine.Get("WorkOrderLineId=@@WorkOrderLine.Id AND ItemId=@@Item.Id AND AddressId=@@Address.Id @parametre")
        If(@@SlipLine.Id="")
            ReturnForm()
        EndIf()
        ShowMessage({"title":"Bilgi","message":"Sayım Güncellenecek","buttons":"Tamam"},@sec)
        Goto(StokSetet)
    EndIf()
    StokSetet:
        Set(@SayimKontrol,2)
        If(@@Item.TrackingType="0")
            ItemTracking.Get("LineType=5 AND TrCode=5 AND SlipLineId=@@SlipLine.Id @parametre")
        Else()
            ItemTracking.Get("LineType=5 AND TrCode=5 AND SlipLineId=@@SlipLine.Id AND TrackingNumber='@takipno' @parametre")
        EndIf()
        Set(@sayimmiktar,@@ItemTracking.Quantity)
        ReturnForm()
EndForm()

BeginForm(ItemAra)
    KeyFunction("ESC",Goto(FormReturn))
    Item:
        ResetVariables({"name":["@@Item","@item_arama_list"]})
        Input(0,0,"Malzeme Kodu/Adı Girin",{"type":"text", "min":"1", "max":"30"},@item_text)
        Item.Get("Code='@item_text' OR Name='@item_text'")
        If(@@Item.Id="")
            Item.List("Name LIKE '%'+@item_text+'%'","",@item_arama_list)
            If(@item_arama_list.rowCount = 0)
                Item.List("Code LIKE '%'+@item_text+'%'","",@item_arama_list)
                If(@item_arama_list.rowCount = 0)
                    Beep(2)
                    ShowMessage({"title":"Hata!","message":"Verilen bilgilerle kayıt bulunamadı!","buttons":"Tamam"},@hata)
                    Goto(Item)
                EndIf()   
            EndIf()  
        EndIf() 
    Liste:
        PopupView(@item_arama_list.rows,{"mode":"list","title":"Malzeme Listesi","fields":["Code|Kodu|15|L","Name|Açıklama|150|L"]},@secim)
        If(@secim>@item_arama_list.rowCount)
            ShowMessage({"title":"Hata","message":"Hatalı Seçim","buttons":"Tekrar Dene"},@hata)
            Goto(Liste)
        EndIf()
        Item.Get(@item_arama_list.rows.@secim.Id)
        ShowMessage({"title":"Malzeme Onay","message":"@@Item.Code\n@@Item.Name","buttons":"Tamam|İptal"},@mlzonay)
        If(@mlzonay=2,Goto(Liste))
    FormReturn:
        Set(@barkod,@@Item.Code)
        ReturnForm()
EndForm()